1 files changed, 66 insertions, 0 deletions
diff --git a/buteo-plugins/buteo-sync-plugin-fediverse-notifications/buteo-sync-plugin-fediverse-notifications.pro b/buteo-plugins/buteo-sync-plugin-fediverse-notifications/buteo-sync-plugin-fediverse-notifications.pro
new file mode 100644
index 0000000..0ba9d2f
--- /dev/null
+++ b/buteo-plugins/buteo-sync-plugin-fediverse-notifications/buteo-sync-plugin-fediverse-notifications.pro
@@ -0,0 +1,66 @@
+# SPDX-FileCopyrightText: 2013 - 2026 Jolla Ltd.
+#
+# SPDX-License-Identifier: BSD-3-Clause
+
+TARGET = fediverse-notifications-client
+
+QT -= gui
+
+include($$PWD/../buteo-common/buteo-common.pri)
+include($$PWD/../../common/common.pri)
+
+TS_FILE = $$OUT_PWD/lipstick-jolla-home-fediverse-notifications.ts
+EE_QM = $$OUT_PWD/lipstick-jolla-home-fediverse-notifications_eng_en.qm
+
+ts.commands += lupdate $$PWD -ts $$TS_FILE
+ts.CONFIG += no_check_exist no_link
+ts.output = $$TS_FILE
+ts.input = .
+
+ts_install.files = $$TS_FILE
+ts_install.path = /usr/share/translations/source
+ts_install.CONFIG += no_check_exist
+
+engineering_english.commands += lrelease -idbased $$TS_FILE -qm $$EE_QM
+engineering_english.CONFIG += no_check_exist no_link
+engineering_english.depends = ts
+engineering_english.input = $$TS_FILE
+engineering_english.output = $$EE_QM
+
+engineering_english_install.path = /usr/share/translations
+engineering_english_install.files = $$EE_QM
+engineering_english_install.CONFIG += no_check_exist
+
+QMAKE_EXTRA_TARGETS += ts engineering_english
+PRE_TARGETDEPS += ts engineering_english
+
+CONFIG += link_pkgconfig
+PKGCONFIG += mlite5 nemonotifications-qt5
+
+INCLUDEPATH += $$PWD
+
+SOURCES += \
+    $$PWD/fediversedatatypesyncadaptor.cpp \
+    $$PWD/fediversenotificationsplugin.cpp \
+    $$PWD/fediversenotificationssyncadaptor.cpp
+
+HEADERS += \
+    $$PWD/fediversedatatypesyncadaptor.h \
+    $$PWD/fediversenotificationsplugin.h \
+    $$PWD/fediversenotificationssyncadaptor.h
+
+OTHER_FILES += \
+    $$PWD/fediverse-notifications.xml \
+    $$PWD/fediverse.Notifications.xml
+
+TEMPLATE = lib
+CONFIG += plugin
+target.path = $$[QT_INSTALL_LIBS]/buteo-plugins-qt5/oopp
+
+sync.path = /etc/buteo/profiles/sync
+sync.files = fediverse.Notifications.xml
+
+client.path = /etc/buteo/profiles/client
+client.files = fediverse-notifications.xml
+
+INSTALLS += target sync client ts_install engineering_english_install