# SPDX-FileCopyrightText: 2013 - 2026 Jolla Ltd.
#
# SPDX-License-Identifier: BSD-3-Clause

TEMPLATE = lib
TARGET = jollaeventsviewfediverseplugin
TARGET = $$qtLibraryTarget($$TARGET)

MODULENAME = com/jolla/eventsview/fediverse
TARGETPATH = $$[QT_INSTALL_QML]/$$MODULENAME

QT -= gui
QT += qml network
CONFIG += plugin link_pkgconfig
PKGCONFIG += socialcache accounts-qt5 libsignon-qt5 sailfishaccounts

include($$PWD/../../common/common.pri)

TS_FILE = $$OUT_PWD/lipstick-jolla-home-fediverse.ts
EE_QM = $$OUT_PWD/lipstick-jolla-home-fediverse_eng_en.qm

ts.commands += lupdate $$PWD -ts $$TS_FILE
ts.CONFIG += no_check_exist no_link
ts.output = $$TS_FILE
ts.input = .

ts_install.files = $$TS_FILE
ts_install.path = /usr/share/translations/source
ts_install.CONFIG += no_check_exist

# should add -markuntranslated "-" when proper translations are in place (or for testing)
engineering_english.commands += lrelease -idbased $$TS_FILE -qm $$EE_QM
engineering_english.CONFIG += no_check_exist no_link
engineering_english.depends = ts
engineering_english.input = $$TS_FILE
engineering_english.output = $$EE_QM

engineering_english_install.path = /usr/share/translations
engineering_english_install.files = $$EE_QM
engineering_english_install.CONFIG += no_check_exist

QMAKE_EXTRA_TARGETS += ts engineering_english
PRE_TARGETDEPS += ts engineering_english

INSTALLS += ts_install engineering_english_install

HEADERS += \
    fediversepostactions.h \
    fediversepostsmodel.h

SOURCES += \
    fediversepostactions.cpp \
    fediversepostsmodel.cpp \
    plugin.cpp

qml.files = fediverse-delegate.qml FediverseFeedItem.qml
qml.path = /usr/share/lipstick/eventfeed/

import.files = qmldir
import.path = $$TARGETPATH
target.path = $$TARGETPATH

OTHER_FILES += $$qml.files $$import.files

INSTALLS += target import qml