1 files changed, 61 insertions, 0 deletions
diff --git a/eventsview-plugins/eventsview-plugin-mastodon/eventsview-plugin-mastodon.pro b/eventsview-plugins/eventsview-plugin-mastodon/eventsview-plugin-mastodon.pro
new file mode 100644
index 0000000..229f38a
--- /dev/null
+++ b/eventsview-plugins/eventsview-plugin-mastodon/eventsview-plugin-mastodon.pro
@@ -0,0 +1,61 @@
+TEMPLATE = lib
+TARGET = jollaeventsviewmastodonplugin
+TARGET = $$qtLibraryTarget($$TARGET)
+
+MODULENAME = com/jolla/eventsview/mastodon
+TARGETPATH = $$[QT_INSTALL_QML]/$$MODULENAME
+
+QT += qml
+CONFIG += plugin link_pkgconfig
+PKGCONFIG += socialcache
+
+include($$PWD/../../common/common.pri)
+
+TS_FILE = $$OUT_PWD/lipstick-jolla-home-mastodon.ts
+EE_QM = $$OUT_PWD/lipstick-jolla-home-mastodon_eng_en.qm
+
+ts.commands += lupdate $$PWD -ts $$TS_FILE
+ts.CONFIG += no_check_exist no_link
+ts.output = $$TS_FILE
+ts.input = .
+
+ts_install.files = $$TS_FILE
+ts_install.path = /usr/share/translations/source
+ts_install.CONFIG += no_check_exist
+
+# should add -markuntranslated "-" when proper translations are in place (or for testing)
+engineering_english.commands += lrelease -idbased $$TS_FILE -qm $$EE_QM
+engineering_english.CONFIG += no_check_exist no_link
+engineering_english.depends = ts
+engineering_english.input = $$TS_FILE
+engineering_english.output = $$EE_QM
+
+engineering_english_install.path = /usr/share/translations
+engineering_english_install.files = $$EE_QM
+engineering_english_install.CONFIG += no_check_exist
+
+QMAKE_EXTRA_TARGETS += ts engineering_english
+PRE_TARGETDEPS += ts engineering_english
+
+INSTALLS += ts_install engineering_english_install
+
+HEADERS += \
+    abstractsocialcachemodel.h \
+    abstractsocialcachemodel_p.h \
+    mastodonpostsmodel.h
+
+SOURCES += \
+    abstractsocialcachemodel.cpp \
+    mastodonpostsmodel.cpp \
+    plugin.cpp
+
+qml.files = mastodon-delegate.qml MastodonFeedItem.qml
+qml.path = /usr/share/lipstick/eventfeed/
+
+import.files = qmldir
+import.path = $$TARGETPATH
+target.path = $$TARGETPATH
+
+OTHER_FILES += $$qml.files $$import.files
+
+INSTALLS += target import qml