blob: 229f38a2d01e4020571433d9855537586568fc32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
TEMPLATE = lib
TARGET = jollaeventsviewmastodonplugin
TARGET = $$qtLibraryTarget($$TARGET)
MODULENAME = com/jolla/eventsview/mastodon
TARGETPATH = $$[QT_INSTALL_QML]/$$MODULENAME
QT += qml
CONFIG += plugin link_pkgconfig
PKGCONFIG += socialcache
include($$PWD/../../common/common.pri)
TS_FILE = $$OUT_PWD/lipstick-jolla-home-mastodon.ts
EE_QM = $$OUT_PWD/lipstick-jolla-home-mastodon_eng_en.qm
ts.commands += lupdate $$PWD -ts $$TS_FILE
ts.CONFIG += no_check_exist no_link
ts.output = $$TS_FILE
ts.input = .
ts_install.files = $$TS_FILE
ts_install.path = /usr/share/translations/source
ts_install.CONFIG += no_check_exist
# should add -markuntranslated "-" when proper translations are in place (or for testing)
engineering_english.commands += lrelease -idbased $$TS_FILE -qm $$EE_QM
engineering_english.CONFIG += no_check_exist no_link
engineering_english.depends = ts
engineering_english.input = $$TS_FILE
engineering_english.output = $$EE_QM
engineering_english_install.path = /usr/share/translations
engineering_english_install.files = $$EE_QM
engineering_english_install.CONFIG += no_check_exist
QMAKE_EXTRA_TARGETS += ts engineering_english
PRE_TARGETDEPS += ts engineering_english
INSTALLS += ts_install engineering_english_install
HEADERS += \
abstractsocialcachemodel.h \
abstractsocialcachemodel_p.h \
mastodonpostsmodel.h
SOURCES += \
abstractsocialcachemodel.cpp \
mastodonpostsmodel.cpp \
plugin.cpp
qml.files = mastodon-delegate.qml MastodonFeedItem.qml
qml.path = /usr/share/lipstick/eventfeed/
import.files = qmldir
import.path = $$TARGETPATH
target.path = $$TARGETPATH
OTHER_FILES += $$qml.files $$import.files
INSTALLS += target import qml
|
